adminandClaude Opus 5
79843aa2ae
Erster Stand der Hintergrundprozesse, die auf der Synology unter /volume1/homes/wagner/SolarManager laufen: der Manager selbst, die Sammler je Geraet, die MQTT-Bruecke, der Wecker und - neu hinzugezogen - der AutoAction-Runner, der als Hintergrundprozess hierher gehoert und nicht ins Web-Verzeichnis. Zugangsdaten stehen nicht mehr im Quelltext, sondern in config.ini, die nicht mit eingecheckt wird. Vorlage ist config.ini.example, gelesen wird sie von konfig.py. Betroffen waren solarManager.py (Datenbank und Wattpilot), zeit.py, gatherWaterData.py, wecker.py und skoda_testdaten.py, das sich das Passwort bisher aus dem Quelltext eines anderen Moduls herausgesucht hat. Die Kia-Anbindung ist mit dem Fahrzeug entfallen: kiaTest.py, gatherCarData.py und hyundai_kia_connect_api sind nicht mehr dabei, ebenso gatherInverterData.py, auf das nur noch eine auskommentierte Zeile zeigte. Die mitgelieferten Bibliotheken bleiben im Repository - die NAS hat kein pip, sie muessen neben den Skripten liegen. Co-Authored-By: Claude Opus 5 <noreply@anthropic.com>
57 lines
1.5 KiB
Cython
57 lines
1.5 KiB
Cython
from cpython cimport PyBytes_AsString
|
|
|
|
|
|
#from cpython cimport PyByteArray_AsString # cython still not exports that
|
|
cdef extern from "Python.h":
|
|
char* PyByteArray_AsString(bytearray ba) except NULL
|
|
|
|
from libc.stdint cimport uint32_t, uint64_t, uintmax_t
|
|
|
|
|
|
def _websocket_mask_cython(object mask, object data):
|
|
"""Note, this function mutates its `data` argument
|
|
"""
|
|
cdef:
|
|
Py_ssize_t data_len, i
|
|
# bit operations on signed integers are implementation-specific
|
|
unsigned char * in_buf
|
|
const unsigned char * mask_buf
|
|
uint32_t uint32_msk
|
|
uint64_t uint64_msk
|
|
|
|
assert len(mask) == 4
|
|
|
|
if not isinstance(mask, bytes):
|
|
mask = bytes(mask)
|
|
|
|
if isinstance(data, bytearray):
|
|
data = <bytearray>data
|
|
else:
|
|
data = bytearray(data)
|
|
|
|
data_len = len(data)
|
|
in_buf = <unsigned char*>PyByteArray_AsString(data)
|
|
mask_buf = <const unsigned char*>PyBytes_AsString(mask)
|
|
uint32_msk = (<uint32_t*>mask_buf)[0]
|
|
|
|
# TODO: align in_data ptr to achieve even faster speeds
|
|
# does it need in python ?! malloc() always aligns to sizeof(long) bytes
|
|
|
|
if sizeof(size_t) >= 8:
|
|
uint64_msk = uint32_msk
|
|
uint64_msk = (uint64_msk << 32) | uint32_msk
|
|
|
|
while data_len >= 8:
|
|
(<uint64_t*>in_buf)[0] ^= uint64_msk
|
|
in_buf += 8
|
|
data_len -= 8
|
|
|
|
|
|
while data_len >= 4:
|
|
(<uint32_t*>in_buf)[0] ^= uint32_msk
|
|
in_buf += 4
|
|
data_len -= 4
|
|
|
|
for i in range(0, data_len):
|
|
in_buf[i] ^= mask_buf[i]
|