initial commit

2025-03-21 09:59:09 +01:00
parent 59637f4fa8
commit f690d03c57
355 changed files with 297020 additions and 0 deletions
@@ -0,0 +1,193 @@
+/**
+ *
+ * @license MIT License
+ *
+ * Copyright (c) 2023 lewis he
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining a copy
+ * of this software and associated documentation files (the "Software"), to deal
+ * in the Software without restriction, including without limitation the rights
+ * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+ * copies of the Software, and to permit persons to whom the Software is
+ * furnished to do so, subject to the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be included in all
+ * copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+ * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+ * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+ * SOFTWARE.
+ *
+ * @file      LTR553ALS_Sensor.ino
+ * @author    Lewis He (lewishe@outlook.com)
+ * @date      2023-09-09
+ *
+ */
+#include <Wire.h>
+#include <SPI.h>
+#include <Arduino.h>
+#include "SensorLTR553.hpp"
+
+#ifndef SENSOR_SDA
+#define SENSOR_SDA  5
+#endif
+
+#ifndef SENSOR_SCL
+#define SENSOR_SCL  6
+#endif
+
+#ifndef SENSOR_IRQ
+#define SENSOR_IRQ  21
+#endif
+
+SensorLTR553 als;
+
+void setup()
+{
+    Serial.begin(115200);
+    while (!Serial);
+
+    pinMode(SENSOR_IRQ, INPUT_PULLUP);
+
+    if (!als.begin(Wire, SENSOR_SDA, SENSOR_SCL)) {
+        Serial.println("Failed to find LTR553 - check your wiring!");
+        while (1) {
+            delay(1000);
+        }
+    }
+
+    Serial.println("Init LTR553 Sensor success!");
+
+    // Set the ambient light high and low thresholds.
+    // If the value exceeds or falls below the set value, an interrupt will be triggered.
+    als.setLightSensorThreshold(10, 200);
+
+    // Set the high and low thresholds of the proximity sensor.
+    // If the value exceeds or falls below the set value, an interrupt will be triggered.
+    als.setProximityThreshold(10, 30);
+
+    // Controls the Light Sensor N number of times the measurement data is outside the range
+    // defined by the upper and lower threshold limits before asserting the interrupt.
+    als.setLightSensorPersists(5);
+
+    // Controls the Proximity  N number of times the measurement data is outside the range
+    // defined by the upper and lower threshold limits before asserting the interrupt.
+    als.setProximityPersists(5);
+
+    /*
+    *  ALS_IRQ_ACTIVE_LOW, // INT pin is considered active when it is a logic 0 (default)
+    *  ALS_IRQ_ACTIVE_HIGH // INT pin is considered active when it is a logic 1
+    * * */
+    als.setIRQLevel(SensorLTR553::ALS_IRQ_ACTIVE_LOW);
+
+    /*
+    *  ALS_IRQ_ONLY_PS,    // Only PS measurement can trigger interrupt
+    *  ALS_IRQ_ONLY_ALS,   // Only ALS measurement can trigger interrupt
+    *  ALS_IRQ_BOTH,       // Both ALS and PS measurement can trigger interrupt
+    * * * */
+    als.enableIRQ(SensorLTR553::ALS_IRQ_BOTH);
+
+    /*
+    *   ALS_GAIN_1X  ,   -> 1 lux to 64k lux (default)
+    *   ALS_GAIN_2X  ,   -> 0.5 lux to 32k lux
+    *   ALS_GAIN_4X  ,   -> 0.25 lux to 16k lux
+    *   ALS_GAIN_8X  ,   -> 0.125 lux to 8k lux
+    *   ALS_GAIN_48X ,   -> 0.02 lux to 1.3k lux
+    *   ALS_GAIN_96X ,   -> 0.01 lux to 600 lux
+    * */
+    als.setLightSensorGain(SensorLTR553::ALS_GAIN_8X);
+
+    /*
+    *   PS_LED_PLUSE_30KHZ,
+    *   PS_LED_PLUSE_40KHZ,
+    *   PS_LED_PLUSE_50KHZ,
+    *   PS_LED_PLUSE_60KHZ,
+    *   PS_LED_PLUSE_70KHZ,
+    *   PS_LED_PLUSE_80KHZ,
+    *   PS_LED_PLUSE_90KHZ,
+    *   PS_LED_PLUSE_100KHZ,
+    * * * * * * * * * * */
+    als.setPsLedPulsePeriod(SensorLTR553::PS_LED_PLUSE_100KHZ);
+
+
+    /*
+    *   PS_LED_DUTY_25,
+    *   PS_LED_DUTY_50,
+    *   PS_LED_DUTY_75,
+    *   PS_LED_DUTY_100,
+    * * * */
+    als.setPsLedDutyCycle(SensorLTR553::PS_LED_DUTY_100);
+
+
+    /*
+    *   PS_LED_CUR_5MA,
+    *   PS_LED_CUR_10MA,
+    *   PS_LED_CUR_20MA,
+    *   PS_LED_CUR_50MA,
+    *   PS_LED_CUR_100MA,
+    * * * * * * * */
+    als.setPsLedCurrent(SensorLTR553::PS_LED_CUR_50MA);
+
+    /*
+    *   PS_MEAS_RATE_50MS,
+    *   PS_MEAS_RATE_70MS,
+    *   PS_MEAS_RATE_100MS,
+    *   PS_MEAS_RATE_200MS,
+    *   PS_MEAS_RATE_500MS,
+    *   PS_MEAS_RATE_1000MS,
+    *   PS_MEAS_RATE_2000MS,
+    *   PS_MEAS_RATE_10MS
+    * * * * * * * */
+    als.setProximityRate(SensorLTR553::PS_MEAS_RATE_200MS);
+
+    // Number of pulses
+    als.setPsLedPulses(1);
+
+    // Enable proximity sensor saturation indication
+    als.enablePsIndicator();
+
+    // Enable ambient light sensor
+    als.enableLightSensor();
+
+    // Enable proximity sensor
+    als.enableProximity();
+
+}
+
+bool canRead()
+{
+#if SENSOR_IRQ != -1
+    return digitalRead(SENSOR_IRQ) == LOW;
+#else
+    static uint32_t lastReadMillis;
+    if (millis() > lastReadMillis) {
+        lastReadMillis = millis() + 500;
+        return true;
+    }
+    return false;
+#endif
+}
+
+void loop()
+{
+    /*
+    * PS Saturation Flag is used for monitoring the internal IC saturation.
+    * It will be flagged when the IC has reached saturation
+    * and not able to perform any further PS measurement
+    * */
+    bool saturated = false;
+    if (canRead()) {
+        Serial.print(" ALS: CH1:"); Serial.print(als.getLightSensor(1));
+        Serial.print(" -  CH0:"); Serial.print(als.getLightSensor(0));
+        Serial.print(" -  PS:"); Serial.print(als.getProximity(&saturated));
+        Serial.print(" -  "); Serial.println(saturated ? "PS saturated" : "PS not saturated");
+    }
+    delay(5);
+}
+
+
+